#まずはグラフのお化粧
set log y
set mytics 10
set grid ytics mytics #これでかなり細かいgridがかける

set xlabel "log2(N)"
set ylabel "something"

set term png size 1080, 1080 fontscale 2.0 noenhanced #sizeは適当でいいけど、小さすぎると見にくいので注意
set output "pic_multi_axis.png"

set size 1.0, 0.55 #1.0は固定
# 0.55の部分に入る数字をAと置いておく、後のことも考えて帳尻あわせが必要
# あとに出てくるset originのyの値2つとA + 0.30 + 0.15 = 1.0になるようにAを書いておく

# marginは隙間のサイズのこと bは底(bottom)、lは左、rは右
# lmarginはylabelが入る関係で、ある程度の大きさを取っておく必要がある
# 一度 set lmargin 0としてみたらいい、1つめのx軸と2つめのx軸がずれてしまう
set bmargin 0 #上記のA+0.3+0.15=1の計算のために0にしておく
set lmargin 10
set rmargin 10 #これはいらないかもしれない

set multiplot #ここがミソ
set origin 0, 0.3 #1枚目の図をどこから書くかを決めている(0, 0.3)の位置から書く、つまり少し下に隙間を開ける

# このrange指定が大事、このrangeと2枚目の軸のrangeが1対1で対応するように設定する
set xrange [10:25]
set yrange [100:10000]

# 適当にプロット(ここでreplotを使うのはNG)
plot "data1.txt" w lp pt 5 ps 2 title "data1", \
"data2.txt" w lp pt 5 ps 2 title "data2"

# 2枚目のグラフを配置する
set origin 0, 0.15
# ここもミソ、x軸以外のいらない部分をすべて消している(もしかしたら余計なオプションを書いてるかもしれない)
unset ytics
unset y2tics
set nomy2tics
set xtics nomirror
set border 1
unset grid
# 2つめのz軸のラベルを指定する
set xlabel "T[s] at f_s=4096[Hz]"
# y軸のラベルは消しておかないと、もう一度表示されるので注意
set ylabel " "

set log x

# このあたりは1つめのx軸と1対1で対応するようにxticsで手で配置しているだけ
set xtics (0.25, 1, 4, 16, 64, 256, 1024, 4096)
set xrange[0.25:8192]
# yrangeは何も書かないと上記のものが反映されてしまう、とりあえずデータ点がプロットされないような範囲を取っておけばOK
set yrange[0.1:0.2]
plot "data1.txt" u (2**$1/4096.0):(0.001) notitle

unset multiplot

set log y
set mytics 10
set grid ytics mytics

set xlabel "log2(N)"
set ylabel "something"

set term png size 1080, 1080 fontscale 2.0 noenhanced
set output "pic_multi_axis.png"

set size 1.0, 0.55

set bmargin 0
set lmargin 10
set rmargin 10

set multiplot
set origin 0, 0.3

set xrange [10:25]
set yrange [100:10000]

plot "data1.txt" w lp pt 5 ps 2 title "data1", \
"data2.txt" w lp pt 5 ps 2 title "data2"

set origin 0, 0.15
unset ytics
unset y2tics
set nomy2tics
set xtics nomirror
set border 1
unset grid
set xlabel "T[s] at f_s=4096[Hz]"
set ylabel " "

set log x

set xtics (0.25, 1, 4, 16, 64, 256, 1024, 4096)
set xrange[0.25:8192]
set yrange[0.1:0.2]
plot "data1.txt" u (2**$1/4096.0):(0.001) notitle

unset multiplot